build.gradle

/*
 * Copyright (C) 2016 BROADSoftware
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */


plugins {
  id 'nebula.ospackage' version '4.10.0'
}

defaultTasks 'uberJars'
 
group = 'com.kappaware.jdctopic'

apply plugin: 'scala'
apply plugin: 'eclipse'


repositories {
    jcenter()
}


configurations {
	compileAndJar
	compile.extendsFrom(compileAndJar)
}

dependencies {
	compile "org.log4s:log4s_${scalaVersion.substring(0,4)}:$log4sVersion"
 	compile "org.slf4j:slf4j-log4j12:$sl4jLog4jVersion"
    compile "org.slf4j:slf4j-api:$sl4jApiVersion"
    compile "log4j:log4j:$log4jVersion"
    compileAndJar "net.sf.jopt-simple:jopt-simple:$joptVersion"
    //compile "com.fasterxml.jackson.jr:jackson-jr-objects:$jacksonJrVersion"
 	compile "org.scala-lang:scala-library:$scalaVersion" // To force $scalaVersion, otherwise, an oldest one will be pulled by kafka or other lib 
 	compile "org.apache.kafka:kafka_${scalaVersion.substring(0,4)}:$kafkaVersion"
 	compileAndJar "com.esotericsoftware.yamlbeans:yamlbeans:$yamlbeansVersion"
    testCompile "junit:junit:$junitVersion"
}


jar {
	exclude("log4j.xml")
	rename("log4j-jar.xml", "log4j.xml")
}

// Refer to https://issues.gradle.org/browse/GRADLE-1010
eclipseJdt.doLast( {
	File f = file('.settings/org.eclipse.core.resources.prefs')
   	f.write('eclipse.preferences.version=1\n')
   	f.append('encoding/<project>=UTF-8')
})


//create a single Jar with non system dependencies
task uberJar(type: Jar) {
   classifier 'uber'
	manifest {
        attributes 'Implementation-Title': 'jdctopic', 
        	'Implementation-Version': version,
        	'Main-Class': 'com.kappaware.jdctopic.Main'
    }
    baseName = uberJarBaseName
    from { configurations.compileAndJar.collect { it.isDirectory() ? it : zipTree(it) } }
    with jar
}

task rpm(type: Rpm) {
	summary 'Kafka topic creation tool'
	packageName rpmBaseName
	version versionForRpm
	arch NOARCH
	vendor 'BROADSoftware'
	license 'Apache 2.0'
	os LINUX
	release '1'
	packageDescription 'jdctopic is an Kafka admin tool allowing idempotency on topics definition.'
    
   	from(uberJar.outputs.files) {
	    into '/opt/jdctopic'
	    user 'root'
		group 'root'
		//rename "${fatJarBaseName}(.+).jar", "${fatJarBaseName}.jar"
	    fileMode 0644
    }
    
   	from('scripts/packages/jdctopic') { into '/usr/bin'; user 'root'; group 'root'; fileMode 0755  }
   	from('scripts/packages/log4j.xml') { into '/etc/jdctopic'; user 'root'; group 'root'; fileMode 0644  }
   	from('scripts/packages/setenv.sh') { into '/etc/jdctopic'; user 'root'; group 'root'; fileMode 0644    }
}


List variations = [ 
   [ name: "1.0.0", kafkaVersion: "1.0.0", scalaVersion: "2.11.11"  ],    
   [ name: "1.1.1", kafkaVersion: "1.1.1", scalaVersion: "2.11.11"  ],    
   [ name: "2.0.0", kafkaVersion: "2.0.0", scalaVersion: "2.11.11"  ]    
]
   
   

for (cf in variations) {
   tasks.create(name: "uberJar.${cf.name}", type: GradleBuild) {
        startParameter = project.getGradle().getStartParameter().newInstance()
        startParameter.projectProperties += [kafkaVersion: "${cf.kafkaVersion}"]
        startParameter.projectProperties += [scalaVersion: "${cf.scalaVersion}"]
        startParameter.projectProperties += [uberJarBaseName: "jdctopic.${cf.kafkaVersion}"]
         //println startParameter.projectProperties
       tasks = ['uberJar']
   }
 
   tasks.create(name: "rpm.${cf.name}", type: GradleBuild) {
    startParameter = project.getGradle().getStartParameter().newInstance()
        startParameter.projectProperties += [kafkaVersion: "${cf.kafkaVersion}"]
        startParameter.projectProperties += [scalaVersion: "${cf.scalaVersion}"]
        startParameter.projectProperties += [uberJarBaseName: "jdctopic.${cf.kafkaVersion}"]
        startParameter.projectProperties += [rpmBaseName: "jdctopic.${cf.kafkaVersion}"]
          //println startParameter.projectProperties
        tasks = ['rpm']
   }
}

task rpms(type: GradleBuild) {
  tasks =  [
      'rpm.1.0.0',
      'rpm.1.1.1',
      'rpm.2.0.0'
  ]
}

task uberJars(type: GradleBuild) {
  tasks =  [
      'uberJar.1.0.0',
      'uberJar.1.1.1',
      'uberJar.2.0.0'
  ]
}