-
Notifications
You must be signed in to change notification settings - Fork 9
/
flake.nix
161 lines (153 loc) · 6.06 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
{
description = "cardano-coin-selection";
inputs = {
haskellNix.url = "github:input-output-hk/haskell.nix";
nixpkgs.follows = "haskellNix/nixpkgs-unstable";
iohkNix.url = "github:input-output-hk/iohk-nix";
incl.url = "github:divnix/incl";
flake-utils.url = "github:hamishmack/flake-utils/hkm/nested-hydraJobs";
CHaP.url = "github:intersectmbo/cardano-haskell-packages?ref=repo";
CHaP.flake = false;
};
outputs = inputs: let
supportedSystems = [
"x86_64-linux"
# disabling to reduce CI time initially. Uncomment later
#"x86_64-darwin"
#"aarch64-linux"
#"aarch64-darwin"
];
in
{inherit (inputs) incl;}
// inputs.flake-utils.lib.eachSystem supportedSystems (
system: let
# setup our nixpkgs with the haskell.nix overlays, and the iohk-nix
# overlays...
nixpkgs = import inputs.nixpkgs {
overlays = [
# iohkNix.overlays.crypto provide libsodium-vrf, libblst and libsecp256k1.
inputs.iohkNix.overlays.crypto
# haskellNix.overlay can be configured by later overlays, so need to come before them.
inputs.haskellNix.overlay
# configure haskell.nix to use iohk-nix crypto librairies.
inputs.iohkNix.overlays.haskell-nix-crypto
];
inherit system;
inherit (inputs.haskellNix) config;
};
inherit (nixpkgs) lib;
# see flake `variants` below for alternative compilers
defaultCompiler = "ghc964";
haddockShellCompiler = defaultCompiler;
# We use cabalProject' to ensure we don't build the plan for
# all systems.
cabalProject = nixpkgs.haskell-nix.cabalProject' ({config, ...}: {
src = ./.;
name = "cardano-coin-selection";
compiler-nix-name = lib.mkDefault defaultCompiler;
# we also want cross compilation to windows on linux (and only with default compiler).
#crossPlatforms = p:
# lib.optional (system == "x86_64-linux" && config.compiler-nix-name == defaultCompiler)
# p.mingwW64;
# CHaP input map, so we can find CHaP packages (needs to be more
# recent than the index-state we set!). Can be updated with
#
# nix flake lock --update-input CHaP
#
inputMap = {
"https://chap.intersectmbo.org/" = inputs.CHaP;
};
# tools we want in our shell, from hackage
shell.tools =
{
cabal = "3.10.2.0";
ghcid = "0.8.9";
}
// lib.optionalAttrs (config.compiler-nix-name == defaultCompiler) {
# tools that work only with default compiler
fourmolu = "0.14.0.0";
hlint = "3.6.1";
stylish-haskell = "0.14.5.0";
haskell-language-server = "2.7.0.0";
};
# and from nixpkgs or other inputs
shell.nativeBuildInputs = with nixpkgs; [ gh jq yq-go ];
# disable Hoogle until someone request it
shell.withHoogle = false;
# Skip cross compilers for the shell
shell.crossPlatforms = _: [];
# package customizations as needed. Where cabal.project is not
# specific enough, or doesn't allow setting these.
modules = [
({pkgs, ...}: {
packages.cardano-coin-selection.configureFlags = ["--ghc-option=-Werror"];
packages.cardano-coin-selection.components.tests.unit.build-tools = [
config.hsPkgs.hspec-discover.components.exes.hspec-discover
];
})
{
packages.crypton-x509-system.postPatch = ''
substituteInPlace crypton-x509-system.cabal --replace 'Crypt32' 'crypt32'
'';
}
];
});
# ... and construct a flake from the cabal project
flake = cabalProject.flake (
lib.optionalAttrs (system == "x86_64-linux") {
# on linux, build/test other supported compilers
variants = lib.genAttrs ["ghc8107"] (compiler-nix-name: {
inherit compiler-nix-name;
});
}
);
in
lib.recursiveUpdate flake rec {
project = cabalProject;
# add a required job, that's basically all hydraJobs.
hydraJobs =
nixpkgs.callPackages inputs.iohkNix.utils.ciJobsAggregates
{
ciJobs =
flake.hydraJobs
// {
# This ensure hydra send a status for the required job (even if no change other than commit hash)
revision = nixpkgs.writeText "revision" (inputs.self.rev or "dirty");
};
}
// { haddockShell = devShells.haddockShell; };
legacyPackages = rec {
inherit cabalProject nixpkgs;
# also provide hydraJobs through legacyPackages to allow building without system prefix:
inherit hydraJobs;
# expose cardano-coin-selection binary at top-level
cardano-coin-selection = cabalProject.hsPkgs.cardano-coin-selection.components.library;
};
devShells = let
profilingShell = p: {
# `nix develop .#profiling` (or `.#ghc927.profiling): a shell with profiling enabled
profiling = (p.appendModule {modules = [{enableLibraryProfiling = true;}];}).shell;
};
in
profilingShell cabalProject
# Add GHC 9.6 shell for haddocks
//
{ haddockShell = let
p = cabalProject.appendModule {compiler-nix-name = haddockShellCompiler;};
in
p.shell // (profilingShell p);
};
# formatter used by nix fmt
formatter = nixpkgs.alejandra;
}
);
nixConfig = {
extra-substituters = [
"https://cache.iog.io"
];
extra-trusted-public-keys = [
"hydra.iohk.io:f/Ea+s+dFdN+3Y/G+FDgSq+a5NEWhJGzdjvKNGv0/EQ="
];
allow-import-from-derivation = true;
};
}