Sponge layer application

[rafacmartins]

Hi,
I’m currently running a few simulations of a submesoscale front confined in a zonal channel using Oceananigans. In my current setup, I need to apply a sponge layer at the y-boundaries of my domain as well as at the bottom (due to the propagation of internal waves, which can be observed around 14 days of simulation, 7-8s into the video below on the lower left panel, the plot it's not the best but it's just to illustrate those waves).

GPU_sponge_layer_2_5km_test_half_UHR.mp4

Note: this simulation above only applies the sponge layer only as forcing = (u=mom_sponge, v=mom_sponge, w=mom_sponge), not applying something specific for those waves.

Currently, I’m planning to apply the sponge layer as follows, to make sure that those internal waves are not being reflected.

#--------------- Sponges

const sponge_size = 2.5kilometers
const slope = 1.25kilometers
x, y, z = nodes(grid, (Center(), Center(), Center()))
const ymin = minimum(y)
const ymax = maximum(y)

@inline mask_func(x,y,z) = ((
     tanh((y-(ymax-sponge_size))/slope)
    *tanh((y-(ymin+sponge_size))/slope)
)+1)/2

bottom_mask = GaussianMask{:z}(center=-grid.Lz, width=100meters)

mom_sponge = Relaxation(rate=1/30minutes, mask=mask_func, target=0)
uvw_sponge = Relaxation(rate=1/30minutes, mask=bottom_mask, target=0)

model = HydrostaticFreeSurfaceModel(; grid,
                                    coriolis = FPlane(latitude = 37),
                                    buoyancy = BuoyancyTracer(),
                                    tracers = :b,
                                    forcing = (u=mom_sponge, v=mom_sponge, w=bottom_mask ),
                                    momentum_advection = WENO(),
                                    tracer_advection = WENO())
#---------------------------

My question is: should I also apply the mom_sponge to w, or even apply the bottom_mask to u and v? If so, how could I do this? Would it look something like this?
forcing = (u=(mom_sponge, bottom_mask), v=(mom_sponge, bottom_mask), w=(mom_sponge, bottom_mask) )]

Thank you!

[simone-silvestri]

Hello @rafacmartins.

Note that w is not evolved in the HydrostaticFreeSurfaceModel, but only diagnosed from the continuity equation. You cannot specify a forcing for w in the HydrostaticFreeSurfaceModel. i.e. the w=bottom_mask forcing in your script is doing nothing at the moment. Therefore, applying the bottom_mask to u and v might be a good idea. A damping sponge for the horizontal velocities will typically also reduce vertical velocity due to continuity.

If you want to apply multiple forcings to a variable you indeed pass it as a tuple of forcings, so your syntax is in part correct (a part from the fact that w is not used).

However, you need to wrap the bottom_mask in a Relaxation forcing with a rate and a target (like you did for uvw_sponge). Therefore, you will end up with:

bottom_mask = GaussianMask{:z}(center=-grid.Lz, width=100meters)

north_sponge = Relaxation(rate=1/30minutes, mask=mask_func, target=0)
bottom_sponge = Relaxation(rate=1/30minutes, mask=bottom_mask, target=0)
mom_forcings =  (north_sponge, bottom_sponge)

forcing = (; u = mom_forcings, v = mom_forcings)

[rafacmartins]

Hello @simone-silvestri, thank you for the response!

It was my mistake that I didn't realize that even though we have w in the HydrostaticFreeSurfaceModel it's just an output from the continuity equation.

Also, thank you for the correction in the code, I was wrongly using bottom_mask instead of uvw_sponge .

I applied the suggestion of using the bottom_mask in both u and v and it seems to work, at least in a lower resolution simulation, the reflection of those internal waves seems to have disappeared. I'm running one with the same resolution of the video above and expect to see a positive result.

Again, thank you for your help!