-
Notifications
You must be signed in to change notification settings - Fork 180
/
build.gradle
158 lines (125 loc) · 4.11 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
import net.fabricmc.loom.task.RemapJarTask
plugins {
id 'fabric-loom' version '1.7-SNAPSHOT'
// This dependency is only used to determine the state of the Git working tree so that build artifacts can be
// more easily identified. TODO: Lazily load GrGit via a service only when builds are performed.
id 'org.ajoberstar.grgit' version '5.0.0'
// Mixin config plugin is a subproject for creating lithium's settings from annotations in each mixin package.
id 'net.caffeinemc.mixin-config-plugin' version '1.0-SNAPSHOT'
}
apply from: "${rootProject.projectDir}/gradle/fabric.gradle"
apply from: "${rootProject.projectDir}/gradle/java.gradle"
apply plugin: 'net.caffeinemc.mixin-config-plugin'
loom {
accessWidenerPath = file("src/main/resources/lithium.accesswidener")
mixin.defaultRefmapName = "mixins.lithium.refmap.json"
}
group = project.maven_group
version = "${project.mod_version}${getVersionMetadata()}"
archivesBaseName = "${project.name}-mc${project.minecraft_version}"
sourceSets {
api {
java {
compileClasspath += main.compileClasspath
}
}
main {
java {
compileClasspath += api.output
runtimeClasspath += api.output
}
}
}
tasks.register('apiJar', Jar) {
archiveClassifier.set "api-dev"
from sourceSets.api.output
}
tasks.register('remapApiJar', RemapJarTask) {
dependsOn apiJar
archiveClassifier.set("api")
input = apiJar.archiveFile.get().asFile
addNestedDependencies = false
}
build.dependsOn remapApiJar
jar {
from sourceSets.api.output.classesDirs
from sourceSets.api.output.resourcesDir
}
loom {
runs {
testmodServer {
runDir("testserver");
server()
ideConfigGenerated project.rootProject == project
source sourceSets.main
}
autoTestServer {
runDir("testserver");
inherit testmodServer
vmArg "-Dfabric.autoTest"
}
}
}
repositories {
allprojects {
repositories {
maven { url 'https://jitpack.io' }
}
}
}
dependencies {
//to change the versions see the gradle.properties file
minecraft "com.mojang:minecraft:${project.minecraft_version}"
mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
modImplementation 'com.github.2No2Name:McTester:v0.4.2'
Set<String> fabricApiModulesCompileOnly = [
"fabric-transfer-api-v1"
]
// Add each fabric api module as a compile only dependency
fabricApiModulesCompileOnly.forEach {
modCompileOnly(fabricApi.module(it, "${project.fabric_version}"))
}
compileOnly 'net.caffeinemc:mixin-config-plugin:1.0-SNAPSHOT'
}
createMixinConfig {
inputFiles = file(compileJava.getDestinationDirectory())
includeFiles = file("src/main/java/me/jellysquid/mods/lithium")
outputDirectory = file("src/main/resources/assets/lithium/")
outputDirectoryForSummaryDocument = file(".")
mixinParentPackage = "me.jellysquid.mods.lithium"
modShortName = "Lithium"
}
jar.dependsOn createMixinConfig
processResources.dependsOn createMixinConfig
createMixinConfig.dependsOn compileJava
def getVersionMetadata() {
def build_release = System.getenv("BUILD_RELEASE") == "true"
// CI builds only
if (build_release) {
return "" // no tag whatsoever
}
if (grgit != null) {
def head = grgit.head()
def id = head.abbreviatedId
// Flag the build if the build tree is not clean
if (!grgit.status().clean) {
id += "-dirty"
}
return "+git.${id}"
}
// No tracking information could be found about the build
return "+unknown"
}
//make builds more reproducible
tasks.withType(AbstractArchiveTask) {
reproducibleFileOrder = true
preserveFileTimestamps = false
}
//Mixin hotswap
afterEvaluate {
loom.runs.configureEach {
// https://fabricmc.net/wiki/tutorial:mixin_hotswaps
vmArg "-javaagent:${ configurations.compileClasspath.find { it.name.contains("sponge-mixin") } }"
}
}