-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy pathfunctions_NPC.d
1685 lines (1298 loc) · 48.2 KB
/
functions_NPC.d
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
* Dependencies:
* EngineClasses_G1\oNpc.d, anims_engine.d, functions_oCNpc_engine.d
*/
/*
* NPC_GetWalkMode
* Author: Dalai Zoll
* Original post: https://forum.worldofplayers.de/forum/threads/1090721-Testschleichen?p=17909902&viewfull=1#post17909902
*/
//Standard Gothic walk modes:
//const int NPC_RUN = 0;
//const int NPC_WALK = 1;
//const int NPC_SNEAK = 2;
const int NPC_INWATER = 3;
func int NPC_GetWalkMode (var int slfInstance) {
//0x00622730 public: class zSTRING __thiscall oCAniCtrl_Human::GetWalkModeString(void)
const int oCAniCtrl_Human__GetWalkModeString_G1 = 6432560;
//0x006AAE40 public: class zSTRING __thiscall oCAniCtrl_Human::GetWalkModeString(void)
const int oCAniCtrl_Human__GetWalkModeString_G2 = 6991424;
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return -1; };
if (!slf.AniCtrl) { return -1; };
CALL_RetValIszString();
CALL__thiscall(slf.AniCtrl, MEMINT_SwitchG1G2 (oCAniCtrl_Human__GetWalkModeString_G1, oCAniCtrl_Human__GetWalkModeString_G2));
var string result;
result = CALL_RetValAszstring ();
if (Hlp_StrCmp (result, "RUN")) { return NPC_RUN; };
if (Hlp_StrCmp (result, "WALK")) { return NPC_WALK; };
if (Hlp_StrCmp (result, "SNEAK")) { return NPC_SNEAK; };
if (Hlp_StrCmp (result, STR_EMPTY)) { return NPC_INWATER; };
return -1;
};
/*
*
*/
func int NPC_IsStanding (var int slfInstance) {
//0x006255E0 public: int __thiscall oCAniCtrl_Human::IsStanding(void)
const int oCAniCtrl_Human__IsStanding_G1 = 6444512;
//0x006ADEE0 public: int __thiscall oCAniCtrl_Human::IsStanding(void)
const int oCAniCtrl_Human__IsStanding_G2 = 7003872;
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return FALSE; };
if (!slf.aniCtrl) { return FALSE; };
var int aniCtrlPtr; aniCtrlPtr = slf.aniCtrl;
var int retVal;
const int call = 0;
if (CALL_Begin(call)) {
CALL_PutRetValTo(_@ (retVal));
CALL__thiscall(_@(aniCtrlPtr), MEMINT_SwitchG1G2 (oCAniCtrl_Human__IsStanding_G1, oCAniCtrl_Human__IsStanding_G2));
call = CALL_End();
};
return + retVal;
};
func int NPC_IsWalking (var int slfInstance) {
//0x006257E0 public: int __thiscall oCAniCtrl_Human::IsWalking(void)
const int oCAniCtrl_Human__IsWalking_G1 = 6445024;
//0x006AE0E0 public: int __thiscall oCAniCtrl_Human::IsWalking(void)
const int oCAniCtrl_Human__IsWalking_G2 = 7004384;
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return FALSE; };
if (!slf.AniCtrl) { return FALSE; };
CALL__thiscall(slf.AniCtrl, MEMINT_SwitchG1G2 (oCAniCtrl_Human__IsWalking_G1, oCAniCtrl_Human__IsWalking_G2));
return CALL_RetValAsInt ();
};
//https://forum.worldofplayers.de/forum/threads/859436-Slow-Motion-in-Gothic-1?p=25955246&viewfull=1#post25955246
//HIGHLANDER: focus->GetModel()->SetTimeScale(3.0f);
/*
https://forum.worldofplayers.de/forum/threads/859436-Slow-Motion-in-Gothic-1?p=25957924&viewfull=1#post25957924
.text:004313B0 @h@LERKS:
.text:004313B0 cmp edi, 68160
.text:004313B6 jnz short @@EOWYN
.text:004313B8 test esi, esi
.text:004313BA mov zCTimer ztimer, 0.40000001
.text:004313C4 jz loc_00432171
.text:004313CA lea ecx, [esp+0CCh+var_B9]
.text:004313CE push ecx
.text:004313CF push offset `string' ; "CLERKS"
.text:004313D4 lea ecx, [esp+0D4h+var_B4]
.text:004313D8 call std::string::string(char const *, Std::allocator<char> const &)
.text:004313DD mov [esp+0CCh+var_B8], ebp
.text:004313E1 mov byte ptr [esp+0CCh+var_4], 30h
.text:004313E9 jmp @@view_PrintTimed
.text:004313EE @@EOWYN:
.text:004313EE cmp edi, 50112
.text:004313F4 jnz @@HIGHLANDER
.text:004313FA mov ecx, [esp+0CCh+focus]
.text:004313FE test ecx, ecx
.text:00431400 jz loc_00432171
.text:00431406 call oCNPC::GetModel(void)
.text:0043140B test esi, esi
.text:0043140D mov dword ptr [eax+1D0h], 0.40000001
*/
func void NPC_SetTimeScale (var int slfInstance, var int f) {
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return; };
var int ptr; ptr = oCNPC_GetModel (slf);
//1D0h = 464
if (ptr) {
//var int timeScale; //G1 464 float timeScale;
//var int timeScale; //G2A 508 float timeScale;
MEM_WriteInt (ptr + MEMINT_SwitchG1G2 (464, 508), f);
};
};
func int NPC_GetNPCState (var int slfInstance) {
//Here we have inconsistency with class declaration in G1/G2A - different naming, so we have to work with offset instead
//oCNpc.state_vfptr // 0x0470
//oCNpc.state_vtbl // 0x0588
var oCNpc slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return 0; };
var int offset; offset = MEMINT_SwitchG1G2 (1136, 1416);
return (_@ (slf) + offset);
};
func string NPC_GetRoutineName (var int slfInstance) {
// var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
// if (!Hlp_IsValidNPC (slf)) { return STR_EMPTY; };
//
// var int ptr; ptr = _@ (slf);
//
// //var func daily_routine; //G1 0x0218 int
// //var func daily_routine; //G2 0x0260 int
//
// var int offset; offset = MEMINT_SwitchG1G2 (536, 608);
//
// var int symbID; symbID = MEM_ReadInt (ptr + offset);
//
// if (symbID > 0) && (symbID < currSymbolTableLength) {
// var zCPar_symbol symb; symb = _^ (MEM_GetSymbolByIndex (symbID));
// return symb.name;
// };
//
// return STR_EMPTY;
//0x006C6C10 public: class zSTRING __thiscall oCNpc_States::GetRoutineName(void)
const int oCNpc_States__GetRoutineName_G1 = 7105552;
//0x0076E180 public: class zSTRING __thiscall oCNpc_States::GetRoutineName(void)
const int oCNpc_States__GetRoutineName_G2 = 7790976;
var int statePtr; statePtr = NPC_GetNPCState (slfInstance);
if (!statePtr) { return STR_EMPTY; };
CALL_RetValIszString ();
CALL__thiscall (statePtr, MEMINT_SwitchG1G2 (oCNpc_States__GetRoutineName_G1, oCNpc_States__GetRoutineName_G2));
return CALL_RetValAszstring ();
};
/*
* Get routine name without prefix and suffix
*/
func string Npc_GetRoutineBaseName (var int slfInstance)
{
var string rtnName; rtnName = NPC_GetRoutineName (slfInstance);
//Double-check just in case
if (STR_StartsWith (rtnName, "RTN_")) {
//Remove prefix
rtnName = STR_Right (rtnName, STR_Len (rtnName) - 4);
};
//Double-check just in case
var C_NPC slf; slf = Hlp_GetNpc(slfInstance);
var string suffix; suffix = ConcatStrings ("_", IntToString (slf.ID));
if (STR_EndsWith (rtnName, suffix)) {
//Remove suffix
rtnName = STR_Left (rtnName, STR_Len (rtnName) - STR_Len (suffix));
};
return rtnName;
};
func int NPC_IsInRoutineName (var int slfInstance, var string rtnName) {
rtnName = STR_Upper (rtnName);
//RTN_ rtnName _ID
var string curRtnName; curRtnName = Npc_GetRoutineBaseName(slfInstance);
//We will allow single wild-card '*'
var int indexWildcard;
indexWildcard = STR_IndexOf (rtnName, "*");
if (indexWildcard > -1) {
var string s1; s1 = mySTR_SubStr (rtnName, 0, indexWildcard);
var string s2; s2 = mySTR_SubStr (rtnName, indexWildcard + 1, STR_Len (rtnName));
return + (STR_StartsWith (curRtnName, s1) && STR_EndsWith (curRtnName, s2));
};
return + (Hlp_StrCmp (rtnName, curRtnName));
};
func string NPC_GetStartAIStateName (var int slfInstance) {
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return STR_EMPTY; };
var int ptr; ptr = _@ (slf);
//var func startAIState; //G1 0x021C int
//var func startAIState; //G2 0x0264 int
var int offset; offset = MEMINT_SwitchG1G2 (540, 612);
var int symbID; symbID = MEM_ReadInt (ptr + offset);
if (symbID > 0) && (symbID < currSymbolTableLength) {
var zCPar_symbol symb; symb = _^ (MEM_GetSymbolByIndex (symbID));
return symb.name;
};
return STR_EMPTY;
};
func string NPC_GetCurrentAIStateName (var int slfInstance) {
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return STR_EMPTY; };
return slf.state_curState_name;
};
func int NPC_IsInActiveVobList (var int slfInstance) {
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return FALSE; };
var int ptr;
var int slfPtr; slfPtr = _@ (slf);
var int i; i = 0;
var int loop; loop = MEM_World.activeVobList_numInArray;
while (i < loop);
ptr = MEM_ReadIntArray(MEM_World.activeVobList_array, i);
if (slfPtr == ptr) {
return TRUE;
};
i += 1;
end;
return FALSE;
};
/*
* Function loops through activeOverlays_array and checks if one of them is testOverlay
* usage: if (NPC_HasOverlay (hero, "HUMANS_DRUNKEN.MDS")) { ...
*/
func int NPC_HasOverlay (var int slfInstance, var string testOverlay)
{
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return FALSE; };
var string overlay;
var int i; i = 0;
var int loop; loop = slf.activeOverlays_numInArray;
while (i < loop);
overlay = MEM_ReadStringArray (slf.activeOverlays_array, i);
if (Hlp_StrCmp (overlay, testOverlay)) {
return TRUE;
};
i += 1;
end;
return FALSE;
};
/*
* Function loops through timedOverlays_next and checks if one of them is testOverlay
* usage: if (NPC_HasTimedOverlay (hero, "HUMANS_SPRINT.MDS")) { ...
*/
func int NPC_HasTimedOverlay (var int slfInstance, var string testOverlay) {
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return FALSE; };
//zCList<oCNpcTimedOverlay> timedOverlays {
//var int timedOverlays_data; // 0x0444 oCNpcTimedOverlay*
//var int timedOverlays_next; // 0x0448 zCList<oCNpcTimedOverlay>*
var int ptr;
var zCList list;
var int timedOverlayPtr;
ptr = slf.timedOverlays_next;
while (ptr);
list = _^ (ptr);
timedOverlayPtr = list.data;
if (timedOverlayPtr) {
var oCNpcTimedOverlay timedOverlay;
timedOverlay = _^ (timedOverlayPtr);
if (Hlp_StrCmp (timedOverlay.mdsOverlayName, testOverlay)) {
return TRUE;
};
};
ptr = list.next;
end;
return FALSE;
};
/*
* Function loops through timedOverlays_next and gets remaining time testOverlay
* usage: if (NPC_GetTimedOverlayTimer (hero, "HUMANS_SPRINT.MDS")) { ...
*/
func int NPC_GetTimedOverlayTimer (var int slfInstance, var string testOverlay) {
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return FLOATNULL; };
//zCList<oCNpcTimedOverlay> timedOverlays {
//var int timedOverlays_data; // 0x0444 oCNpcTimedOverlay*
//var int timedOverlays_next; // 0x0448 zCList<oCNpcTimedOverlay>*
var int ptr;
var zCList list;
var int timedOverlayPtr;
ptr = slf.timedOverlays_next;
while (ptr);
list = _^ (ptr);
timedOverlayPtr = list.data;
if (timedOverlayPtr) {
var oCNpcTimedOverlay timedOverlay;
timedOverlay = _^ (timedOverlayPtr);
if (Hlp_StrCmp (timedOverlay.mdsOverlayName, testOverlay)) {
return timedOverlay.timer;
};
};
ptr = list.next;
end;
return FLOATNULL;
};
/*
* In G1 if NPC drinks speed potions with different times, overlays will be added separately to the list
* oCNpcTimedOverlay time #1
* oCNpcTimedOverlay time #2
*
* As soon as time #1 expires overlay is removed ... even though overlay with time #2 is still 'active' ...
*
* This function loops through timedOverlays_next and removes duplicated timed overlays
* sumValues parameter defines behaviour:
* set it to 0 if you want script to get MAX value from all timers
* set it to 1 if you want script to SUM all timers
*
* usage: if (NPC_RemoveDuplicatedTimedOverlays (hero, "HUMANS_SPRINT.MDS"), 0) { ... //gets only max timer value
* usage: if (NPC_RemoveDuplicatedTimedOverlays (hero, "HUMANS_SPRINT.MDS"), 1) { ... //sums up all timers
*/
func void NPC_RemoveDuplicatedTimedOverlays (var int slfInstance, var string testOverlay, var int sumValues)
{
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return; };
//zCList<oCNpcTimedOverlay> timedOverlays {
//var int timedOverlays_data; // 0x0444 oCNpcTimedOverlay*
//var int timedOverlays_next; // 0x0448 zCList<oCNpcTimedOverlay>*
var int ptr;
var zCList list;
var int timedOverlayPtr;
var oCNpcTimedOverlay timedOverlay;
ptr = slf.timedOverlays_next;
var int i; i = 0;
var int f; f = FLOATNULL;
while (ptr);
list = _^ (ptr);
timedOverlayPtr = list.data;
if (timedOverlayPtr) {
timedOverlay = _^ (timedOverlayPtr);
if (Hlp_StrCmp (timedOverlay.mdsOverlayName, testOverlay)) {
//Sum all timers
if (sumValues) {
f = addf (f, timedOverlay.timer);
} else {
//Get max timer value
if (gf (timedOverlay.timer, f)) {
f = timedOverlay.timer;
};
};
//count how many timed overlays do we have
i += 1;
};
};
ptr = list.next;
end;
//Is there more than 1 timed overlay ?
if (i > 1) {
i = 0;
var int j; j = 0;
if (gf (f, FLOATNULL)) {
ptr = slf.timedOverlays_next;
while (ptr);
list = _^ (ptr);
timedOverlayPtr = list.data;
if (timedOverlayPtr) {
timedOverlay = _^ (timedOverlayPtr);
if (Hlp_StrCmp (timedOverlay.mdsOverlayName, testOverlay)) {
//Update first value with total number
if (i == 0) {
timedOverlay.timer = f;
} else {
//Remove overlay name - this way overlay wont be removed from NPC
timedOverlay.mdsOverlayName = STR_EMPTY;
timedOverlay.timer = FLOATNULL;
};
i += 1;
};
};
j += 1;
ptr = list.next;
end;
};
};
};
/*
* Function loops through timedOverlays_next and removes them
* usage: if (NPC_RemoveTimedOverlay (hero, "HUMANS_SPRINT.MDS")) { ...
*/
func void NPC_RemoveTimedOverlay (var int slfInstance, var string testOverlay) {
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return; };
//zCList<oCNpcTimedOverlay> timedOverlays {
//var int timedOverlays_data; // 0x0444 oCNpcTimedOverlay*
//var int timedOverlays_next; // 0x0448 zCList<oCNpcTimedOverlay>*
var int ptr;
var zCList list;
var int timedOverlayPtr;
ptr = slf.timedOverlays_next;
while (ptr);
list = _^ (ptr);
timedOverlayPtr = list.data;
if (timedOverlayPtr) {
var oCNpcTimedOverlay timedOverlay;
timedOverlay = _^ (timedOverlayPtr);
if (Hlp_StrCmp (timedOverlay.mdsOverlayName, testOverlay)) {
//Remove overlay name - this way overlay wont be removed from NPC
timedOverlay.mdsOverlayName = STR_EMPTY;
timedOverlay.timer = FLOATNULL;
};
};
ptr = list.next;
end;
};
func int NPC_GetBitfield (var int slfInstance, var int bitfield) {
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return 0; };
//Simple true/false values
if (bitfield == oCNpc_bitfield0_showaidebug)
|| (bitfield == oCNpc_bitfield0_showNews)
|| (bitfield == oCNpc_bitfield0_csAllowedAsRole)
|| (bitfield == oCNpc_bitfield0_isSummoned)
|| (bitfield == oCNpc_bitfield0_respawnOn)
|| (bitfield == oCNpc_bitfield0_movlock)
|| (bitfield == oCNpc_bitfield0_drunk)
|| (bitfield == oCNpc_bitfield0_mad)
|| (bitfield == oCNpc_bitfield0_overlay_wounded)
|| (bitfield == oCNpc_bitfield0_inOnDamage)
|| (bitfield == oCNpc_bitfield0_autoremoveweapon)
|| (bitfield == oCNpc_bitfield0_openinventory)
|| (bitfield == oCNpc_bitfield0_askroutine)
|| (bitfield == oCNpc_bitfield0_spawnInRange)
|| (bitfield == oCNpc_bitfield0_body_TexVarNr)
{
return (slf.bitfield[0] & bitfield);
};
if (bitfield == oCNpc_bitfield1_body_TexColorNr) //65535
|| (bitfield == oCNpc_bitfield1_head_TexVarNr) //4294901760
{
return (slf.bitfield[1] & bitfield);
};
if (bitfield == oCNpc_bitfield2_teeth_TexVarNr)
|| (bitfield == oCNpc_bitfield2_guildTrue)
|| (bitfield == oCNpc_bitfield2_drunk_heal)
{
return (slf.bitfield[2] & bitfield);
};
if (bitfield == oCNpc_bitfield3_mad_heal)
|| (bitfield == oCNpc_bitfield3_spells)
{
return (slf.bitfield[3] & bitfield);
};
if (bitfield == oCNpc_bitfield4_bodyState)
{
return (slf.bitfield[4] & bitfield);
};
return 0;
};
func void NPC_SetBitfield (var int slfInstance, var int bitfield, var int value) {
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return; };
//Basically true/false values
if (bitfield == oCNpc_bitfield0_showaidebug)
|| (bitfield == oCNpc_bitfield0_showNews)
|| (bitfield == oCNpc_bitfield0_csAllowedAsRole)
|| (bitfield == oCNpc_bitfield0_isSummoned)
|| (bitfield == oCNpc_bitfield0_respawnOn)
|| (bitfield == oCNpc_bitfield0_movlock)
|| (bitfield == oCNpc_bitfield0_drunk)
|| (bitfield == oCNpc_bitfield0_mad)
|| (bitfield == oCNpc_bitfield0_overlay_wounded)
|| (bitfield == oCNpc_bitfield0_inOnDamage)
|| (bitfield == oCNpc_bitfield0_autoremoveweapon)
|| (bitfield == oCNpc_bitfield0_openinventory)
|| (bitfield == oCNpc_bitfield0_askroutine)
|| (bitfield == oCNpc_bitfield0_spawnInRange)
|| (bitfield == oCNpc_bitfield0_body_TexVarNr)
{
if ((value == 0) || (value == 1)) {
value = bitfield * value;
};
slf.bitfield[0] = (slf.bitfield[0] & ~ bitfield) | value;
return;
};
if (bitfield == oCNpc_bitfield1_body_TexColorNr)
|| (bitfield == oCNpc_bitfield1_head_TexVarNr)
{
slf.bitfield[1] = (slf.bitfield[1] & ~ bitfield) | value;
return;
};
if (bitfield == oCNpc_bitfield2_teeth_TexVarNr)
|| (bitfield == oCNpc_bitfield2_guildTrue)
|| (bitfield == oCNpc_bitfield2_drunk_heal)
{
slf.bitfield[2] = (slf.bitfield[2] & ~ bitfield) | value;
return;
};
if (bitfield == oCNpc_bitfield3_mad_heal)
|| (bitfield == oCNpc_bitfield3_spells)
{
slf.bitfield[3] = (slf.bitfield[3] & ~ bitfield) | value;
return;
};
if (bitfield == oCNpc_bitfield4_bodyState)
{
slf.bitfield[4] = (slf.bitfield[4] & ~ bitfield) | value;
return;
};
};
/*
* Npc_HasVisualBody
* - checks if visual body name starts with specified string
*/
func int Npc_HasVisualBody(var int slfInstance, var string visualBodyPrefix) {
var string visualBody; visualBody = oCNpc_GetVisualBody(slfInstance);
visualBody = STR_Upper(visualBody);
visualBodyPrefix = STR_Upper(visualBodyPrefix);
if (STR_StartsWith(visualBody, visualBodyPrefix)) {
return TRUE;
};
return FALSE;
};
/*
* Npc_CarriesTorch
* - returns true if Npc is carrying torch (checks both hands)
* - updates global variable item with torch in hand
*/
func int Npc_CarriesTorch (var int slfinstance){
var oCNpc slf; slf = Hlp_GetNpc(slfinstance);
if (!Hlp_IsValidNPC(slf)) { return FALSE; };
var int ptr;
var oCItem itm;
//Get pointer to ZS_LEFTHAND
ptr = oCNpc_GetSlotItem(slf, NPC_NODE_LEFTHAND);
//Is there anything in hand?
if (ptr) {
itm = _^ (ptr);
//Is it ItLsTorchBurning / ItLsTorchBurned ?
if ((Hlp_GetinstanceID(itm) == ItLsTorchBurning) || (Hlp_GetinstanceID(itm) == ItLsTorchBurned)) {
item = _^(ptr);
return TRUE;
};
};
//Get pointer to ZS_RIGHTHAND
ptr = oCNpc_GetSlotItem(slf, NPC_NODE_RIGHTHAND);
//Is there anything in hand?
if (ptr) {
itm = _^ (ptr);
//Is it ItLsTorchBurning / ItLsTorchBurned ?
if ((Hlp_GetinstanceID(itm) == ItLsTorchBurning) || (Hlp_GetinstanceID(itm) == ItLsTorchBurned)) {
item = _^(ptr);
return TRUE;
};
};
return FALSE;
};
/*
* Function calls torch exchange & removes overlay when torch is not in ZS_LEFTHAND
*/
func int Npc_DoExchangeTorch (var int slfInstance) {
var C_NPC slf; slf = Hlp_GetNpc(slfInstance);
if (!Hlp_IsValidNpc(slf)) { return FALSE; };
if (!Npc_IsInFightMode(slf, FMODE_NONE)) {
return FALSE;
};
if (oCNpc_DoExchangeTorch(slfInstance)) {
if (!Npc_CarriesTorch(slfInstance)) {
if (Npc_HasVisualBody(slf, VISBODY_PREFIX_HUM)) {
if (Npc_HasOverlay(slfInstance, MDS_HUMANS_TORCH)) {
Mdl_RemoveOverlayMds(slf, MDS_HUMANS_TORCH);
};
} else
if (Npc_HasVisualBody(slf, VISBODY_PREFIX_ORC)) {
if (Npc_HasOverlay(slfInstance, MDS_ORC_TORCH)) {
Mdl_RemoveOverlayMds(slf, MDS_ORC_TORCH);
};
};
};
return TRUE;
};
return FALSE;
};
/*
* Npc_TorchSwitchOff
*/
func void Npc_TorchSwitchOff (var int slfInstance) {
var oCNpc slf; slf = Hlp_GetNPC(slfInstance);
if (!Hlp_IsValidNPC (slf)) { return; };
//Is there anything in hand?
if (Npc_CarriesTorch(slf)) {
//if in right hand then perform DoExchangeTorch to get it back to left hand
var int ptr; ptr = oCNpc_GetSlotItem(slf, NPC_NODE_RIGHTHAND);
if (ptr == _@(item)) {
var int retVal; retVal = oCNpc_DoExchangeTorch(slf);
};
//Use item - will put ItLsTorch back to inventory
oCNpc_EquipPtr(slf, _@(item));
if (Npc_HasVisualBody(slf, VISBODY_PREFIX_HUM)) {
if (Npc_HasOverlay(slfInstance, MDS_HUMANS_TORCH)) {
Mdl_RemoveOverlayMds(slf, MDS_HUMANS_TORCH);
};
} else
if (Npc_HasVisualBody(slf, VISBODY_PREFIX_ORC)) {
if (Npc_HasOverlay(slfInstance, MDS_ORC_TORCH)) {
Mdl_RemoveOverlayMds(slf, MDS_ORC_TORCH);
};
};
};
};
/*
* NPC_TorchSwitchOn
*/
func void NPC_TorchSwitchOn (var int slfInstance) {
var oCNpc slf; slf = Hlp_GetNPC(slfInstance);
if (!Hlp_IsValidNPC (slf)) { return; };
var int ptr;
//Check fight mode!
if (!Npc_IsInFightMode(slf, FMODE_NONE)) {
//Exception for FMODE_MELEE - check talent
if (!Npc_IsInFightMode(slf, FMODE_MELEE)) {
return;
};
//Get weapon pointer - we will allow torch in case of 1H lvl > 0
ptr = oCNpc_GetSlotItem(slf, NPC_NODE_RIGHTHAND);
var int is1H; is1H = oCItem_IsOneHanded(ptr);
if (!is1H) {
return;
};
//Don't allow torches on lvl 0
if (is1H && Npc_GetTalentSkill(slf, NPC_TALENT_1H) == 0) {
return;
};
};
//Get pointer to ZS_LEFTHAND
ptr = oCNpc_GetSlotItem(slf, NPC_NODE_LEFTHAND);
//Is hand empty?
if (!ptr) {
//Search for torches ItLsTorchBurning, ItLsTorchBurned, ItLsTorch
if (!NPC_GetInvItem(slf, ItLsTorchBurning)) {
if (!NPC_GetInvItem(slf, ItLsTorchBurned)) {
if (!NPC_GetInvItem(slf, ItLsTorch)) {
return;
};
};
};
oCNpc_EquipPtr(slf, _@(item));
//Apply overlay
if (Npc_HasVisualBody(slf, VISBODY_PREFIX_HUM)) {
if (!Npc_HasOverlay(slfInstance, MDS_HUMANS_TORCH)) {
Mdl_ApplyOverlayMds(slf, MDS_HUMANS_TORCH);
};
} else
if (Npc_HasVisualBody(slf, VISBODY_PREFIX_ORC)) {
if (!Npc_HasOverlay(slfInstance, MDS_ORC_TORCH)) {
Mdl_ApplyOverlayMds(slf, MDS_ORC_TORCH);
};
};
};
};
/*
* Switches torches on - off
* return -1 if NPC does not have torch
* return 0 if torch was removed
* return 1 if torch was put in hand
*/
func int NPC_TorchSwitchOnOff(var int slfinstance) {
var oCNpc slf; slf = Hlp_GetNPC (slfinstance);
if (!Hlp_IsValidNPC (slf)) { return -1; };
if (Npc_CarriesTorch(slf)) {
Npc_TorchSwitchOff(slf);
return 0;
} else {
Npc_TorchSwitchOn(slf);
if (Npc_CarriesTorch(slf)) {
return 1;
};
};
return -1;
};
func int NPC_GetNode (var int slfInstance, var string nodeName) {
//0x00563F80 public: class zCModelNodeInst * __thiscall zCModel::SearchNode(class zSTRING const &)
const int zCModel__SearchNode_G1 = 5652352;
//0x0057DFF0 public: class zCModelNodeInst * __thiscall zCModel::SearchNode(class zSTRING const &)
const int zCModel__SearchNode_G2 = 5758960;
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return 0; };
var int modelPtr; modelPtr = oCNPC_GetModel (slfInstance);
if (!modelPtr) { return 0; };
var int retVal;
CALL_PutRetValTo(_@(retVal));
CALL_zStringPtrParam (nodeName);
CALL__thiscall (modelPtr, MEMINT_SwitchG1G2 (zCModel__SearchNode_G1, zCModel__SearchNode_G2));
return + retVal;
};
func int NPC_GetNodePositionWorld (var int slfInstance, var string nodeName) {
//0x0055F8C0 public: class zVEC3 __thiscall zCModel::GetNodePositionWorld(class zCModelNodeInst *)
const int zCModel__GetNodePositionWorld_G1 = 5634240;
//0x00579140 public: class zVEC3 __thiscall zCModel::GetNodePositionWorld(class zCModelNodeInst *)
const int zCModel__GetNodePositionWorld_G2 = 5738816;
var int modelPtr; modelPtr = oCNPC_GetModel (slfInstance);
if (!modelPtr) { return 0; };
var int nodePtr; nodePtr = NPC_GetNode (slfInstance, nodeName);
if (!nodePtr) { return 0; };
CALL_RetValIsStruct (12);
CALL_PtrParam (nodePtr);
CALL__thiscall (modelPtr, MEMINT_SwitchG1G2 (zCModel__GetNodePositionWorld_G1, zCModel__GetNodePositionWorld_G2));
return CALL_RetValAsPtr ();
};
func int Npc_GetNodePositionWorldToPos (var int slfInstance, var string nodeName, var int posPtr) {
var int nodePosPtr; nodePosPtr = NPC_GetNodePositionWorld (slfInstance, nodeName);
if (nodePosPtr) {
MEM_CopyBytes(nodePosPtr, posPtr, 12);
MEM_Free(nodePosPtr);
return TRUE;
};
return FALSE;
};
/*
* NPC_GetDistToPos // int
*/
func int NPC_GetDistToPos (var int slfInstance, var int posPtr) {
if (!posPtr) { return -1; };
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return -1; };
var int pos[3];
pos[0] = slf._zCVob_trafoObjToWorld [03];
pos[1] = slf._zCVob_trafoObjToWorld [07];
pos[2] = slf._zCVob_trafoObjToWorld [11];
var int dir[3];
SubVectors (_@ (dir), _@ (pos), posPtr);
return roundf (zVEC3_LengthApprox (_@ (dir)));
};
/*
* NPC_GetDistToVobPtr //int
*/
func int NPC_GetDistToVobPtr (var int slfInstance, var int vobPtr) {
if (!vobPtr) { return -1; };
var zCVob vob; vob = _^ (vobPtr);
var int pos[3];
pos[0] = vob.trafoObjToWorld [03];
pos[1] = vob.trafoObjToWorld [07];
pos[2] = vob.trafoObjToWorld [11];
return + NPC_GetDistToPos (slfInstance, _@ (pos));
};
func int NPC_GetShowAI (var int slfInstance) {
//0x00616080 public: int __thiscall oCAIHuman::GetShowAI(void)
const int oCAIHuman__GetShowAI_G1 = 6381696;
//0x0069D880 public: int __thiscall oCAIHuman::GetShowAI(void)
const int oCAIHuman__GetShowAI_G2 = 6936704;
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return 0; };
if (!slf.human_ai) { return 0; };
var int human_aiPtr; human_aiPtr = slf.human_ai;
var int retVal;
const int call = 0;
if (CALL_Begin(call)) {
CALL_PutRetValTo(_@ (retVal));
CALL__thiscall(_@(human_aiPtr), MEMINT_SwitchG1G2 (oCAIHuman__GetShowAI_G1, oCAIHuman__GetShowAI_G2));
call = CALL_End();
};
return + retVal;
};
func void NPC_SetShowAI (var int slfInstance, var int enable) {
//0x00616060 public: void __thiscall oCAIHuman::SetShowAI(int)
const int oCAIHuman__SetShowAI_G1 = 6381664;
//0x0069D860 public: void __thiscall oCAIHuman::SetShowAI(int)
const int oCAIHuman__SetShowAI_G2 = 6936672;
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return; };
if (!slf.human_ai) { return; };
var int human_aiPtr; human_aiPtr = slf.human_ai;
const int call = 0;
if (CALL_Begin(call)) {
CALL_IntParam(_@ (enable));
CALL__thiscall(_@(human_aiPtr), MEMINT_SwitchG1G2 (oCAIHuman__SetShowAI_G1, oCAIHuman__SetShowAI_G2));
call = CALL_End();
};
};
func void NPC_MobSetIdealPosition (var int slfInstance) {
var oCNPC slf; slf = Hlp_GetNPC (slfInstance);
if (!Hlp_IsValidNPC (slf)) { return; };
if (!slf.interactMob) { return; };
//oCMobInter_ScanIdealPositions (slf.interactMob);
var oCMobInter mob; mob = _^ (slf.interactMob);
if (mob.optimalPosList_next) {
var int i; i = 0;
var int ptr;
var zCList list;
ptr = mob.optimalPosList_next;
while (ptr);
list = _^ (ptr);
ptr = list.data;
if (ptr) {
//TMobOptPos.trafo is at offset 0, so we can read trafo directly from ptr
//AlignVobAt (_@ (slf), ptr); --> copying whole function here - in order to have this file 'standalone'